{
  pkgs ? import <nixpkgs> {},
  system ? builtins.currentSystem,
}: let
  systems_table = {
    "x86_64-linux" = {
      system = "x86_64-unknown-linux-gnu";
      hash = "0cwld65c2rmba2bx40d577pidd70dw9jy00zqihsvdpap8jgplma";
    };
  };
  download_system = systems_table.${system};
in
  pkgs.stdenv.mkDerivation rec {
    pname = "esp-rust";
    version = "1.95.0.0";
    srcs = [
      (builtins.fetchurl
        {
          url = "https://github.com/esp-rs/rust-build/releases/download/v${version}/rust-${version}-${download_system.system}.tar.xz";
          sha256 = download_system.hash;
        })
      (builtins.fetchurl
        {
          url = "https://github.com/esp-rs/rust-build/releases/download/v${version}/rust-src-${version}.tar.xz";
          sha256 = "05vp68gs8h6q4mwrbd5w5w2imjgypx3k1y8shq71rm62g8ryx2vh";
        })
    ];
    sourceRoot = ".";

    preferLocalBuild = true;

    nativeBuildInputs = with pkgs; [
      autoPatchelfHook
    ];

    buildInputs = with pkgs; [
      stdenv.cc.cc.lib
      libz
    ];

    installPhase = ''
      runHook preInstall
      mkdir -p "$out"
      cp -R ./*/*/{bin,share,lib} "$out"
      runHook postInstall
    '';
  }