# Edit this configuration file to define what should be installed on
# your system.  Help is available in the configuration.nix(5) man page
# and in the NixOS manual (accessible by running ‘nixos-help’).
{
  config,
  pkgs,
  inputs,
  ...
}: {
  imports = [
    # Include the results of the hardware scan.
    ./hardware-configuration.nix
    ../../modules/nixos
    inputs.home-manager.nixosModules.default
  ];

  myConfig = {
    enable = true;
    desktop = true;
    gpu.amd.enable = true;
    laptop = true;
  };

  networking.hostName = "MaxNixosLaptop"; # Define your hostname.

  # Define a user account. Don't forget to set a password with ‘passwd’.
  users.users.max = {
    isNormalUser = true;
    description = "Max Känner";
    extraGroups = ["networkmanager" "wheel" "libvirtd" "dialout"];
    shell = pkgs.zsh;
  };

  networking.firewall.enable = false;

  home-manager = {
    extraSpecialArgs = {inherit inputs;};
    users = {
      "max" = import ./home.nix;
    };
  };

  # List packages installed in system profile. To search, run:
  # $ nix search wget
  environment.systemPackages = with pkgs; [
    bambu-studio
    neovim
    wget
    fprintd
    qemu
    home-manager
    (let
      base = appimageTools.defaultFhsEnvArgs;
    in
      buildFHSEnv (base
        // {
          name = "fhs";
          targetPkgs = pkgs: (
            # pkgs.buildFHSUserEnv provides only a minimal FHS environment,
            # lacking many basic packages needed by most software.
            # Therefore, we need to add them manually.
            #
            # pkgs.appimageTools provides basic packages required by most software.
            (base.targetPkgs pkgs)
            ++ [
              pkg-config
              ncurses
              # Feel free to add more packages here if needed.
            ]
          );
          profile = "export FHS=1";
          runScript = "bash";
          extraOutputsToInstall = ["dev"];
        }))
  ];

  fonts.packages = with pkgs; [
    nerdfonts
    montserrat
  ];

  programs.ssh.startAgent = true;
  programs.zsh.enable = true;
  programs.steam.enable = true;

  security.polkit.enable = true;
  environment.sessionVariables.NIXOS_OZONE_WL = "1";

  virtualisation = {
    podman = {
      enable = true;
      dockerCompat = true;
      defaultNetwork.settings.dns_enabled = true;
    };
    libvirtd = {
      enable = true;
      qemu = {
        package = pkgs.qemu_kvm;
        runAsRoot = true;
        swtpm.enable = true;
        ovmf = {
          enable = true;
          packages = [
            (pkgs.OVMF.override {
              secureBoot = true;
              tpmSupport = true;
            })
            .fd
          ];
        };
      };
    };
  };

  # List services that you want to enable:

  # fingerprint unlock
  services.fprintd.enable = true;

  hardware.bluetooth = {
    enable = true;
    powerOnBoot = true;
  };
  services.blueman.enable = true;

  services.udisks2.enable = true;

  services.udev = {
    enable = true;
    packages = with pkgs; [
      picoprobe-udev-rules
      qmk-udev-rules
      game-devices-udev-rules
      android-udev-rules
    ];
  };

  services.pipewire = {
    enable = true;
    alsa.enable = true;
    jack.enable = true;
    pulse.enable = true;
  };

  boot.binfmt.emulatedSystems = ["aarch64-linux"];

  # This value determines the NixOS release from which the default
  # settings for stateful data, like file locations and database versions
  # on your system were taken. It‘s perfectly fine and recommended to leave
  # this value at the release version of the first install of this system.
  # Before changing this value read the documentation for this option
  # (e.g. man configuration.nix or on https://nixos.org/nixos/options.html).
  system.stateVersion = "23.11"; # Did you read the comment?
}